Aminet 21/Aminet 21 (1997)(GTI - Schatztruhe)[!][Oct 1997].iso/Aminet/comm/thor/BounceSpam.lha/BounceSpam.thor

Text File | 1997-08-10 | 5.0 KB | 187 lines

/* Add Spammer's Email address to the GetMail configuration file

   $VER: BounceSpam.thor V1.5 (10.8.97) ©1997 Roy E Brown

   GetMail is © 1996-97 Philip Stokes

   This script will add the current message 'from address' to either the
   'Kill Addresses' or the 'Allowed Addresses' section of GetMail's
   configuration file.

   The 'Kill' option is useful for automatically adding spammers to your kill
   list, as any mail from these addresses is automatically bounced back to the
   sender without being downloaded to your system.

   The 'Allowed' option allows GetMail to receive EMail from the specified
   addresses without asking the user for confirmation first. This option is
   configurable within GetMail - you should read the GetMail documentation
   carefully. You should manually delete the word 'any' from this section if
   you add new addresses.

   The script assumes that you have the following 3 lines at the end of your
   existing 'Kill Addresses';

   <Blank Line>
   #  ===============================================================
   #  Allowed Addresses

   ... and these 2 lines at the end of the file:

   <Blank Line>
   # EOF

   If you haven't touched these lines at all, then the script should work OK.

   This script will only work from within the EMail conference of Thor.

   Please change the variable below to reflect the full path location of SMTP.conf */

UULibPath="Work:Internet_System/usr/lib/SMTP.conf"    /* Full path to SMTP.conf */

/* Please do not alter anything below this line. Thank you */

Vers="BounceSpam V1.5 ©1997 Roy E Brown"
lf='0a'x
lines=0
txt=''

Signal ON Syntax

Options Results

Options FailAt 21

/* Is Thor active? */
If ~Show('P','THOR.01') Then
  Do
    Say "Thor needs to be available for this script"
    Exit
  End

/* Check for Getmail's config file in UULib: */
If ~Exists(UULibPath) Then
  Do
    Address THOR.01
    REQUESTNOTIFY TEXT '"'vers'\n\n   Are you sure that you use GetMail?\n  I cannot find the configuration file.\n\n            UULIB:SMTP.conf" BT "_Exit"'
    Exit
  End

/* Check for BBSRead port. Open if necessary */
If ~Show('P','BBSREAD') Then
  Do
    Address Command
    "run >nil: `GetEnv THOR/THORPath`bin/LoadBBSRead"
    "WaitForPort BBSREAD"
  End

/* Let's get the file open and find out how many lines etc */
If Open(config,UULibPath,r)~=1 Then
  Do
    REQUESTNOTIFY TEXT '"'vers'\n\nUnable to open the Getmail configuration file" BT "_Exit"'
    Exit
  End
Else
  Do Until EOF(config)
    Do
      String=Readln(config)
      lines=lines+1
      txt=txt||string||lf
    End
  txt.lines=string
  End

Call Close(config)

/* Get details of current system and message */
Address THOR.01
CURRENTSYSTEM stem CURRENT
CURRENTMSG stem MSG

MDB_DELETED = 5   /* Message is deleted. */

Address BBSREAD
READBRMESSAGE CURRENT.BBSNAME '"'CURRENT.CONFNAME'"' MSG.MSGNR HEADSTEM Header DATASTEM msgdata
If RC ~=0 Then Call BBSError

If Bittst(MSGDATA.FLAGS,MDB_DELETED) Then
  Do
    Address THOR.01
    REQUESTNOTIFY TEXT '"'vers'\n\nThis message (# 'MSG.MSGNR') has been deleted." BT "_Cancel"'
    Exit
  End

Addr=HEADER.FROMADDR

/* Do we want to edit the address first? */
Address THOR.01
REQUESTSTRING TITLE '"'Vers'" BT "_Done|_Cancel" ID "'addr'" BODY "Do you wish to edit the address?"'
If RC=5 Then Exit
addr=Result

/* What do we want to do - Kill or Accept an address */
Address THOR.01
REQUESTNOTIFY TEXT '"'vers'\n\n   Do you wish to add this address to\n   the ''Kill'' or the ''Accept'' section?\n\n'addr'\n" BT "_Kill|_Accept|_Cancel"'
If Result=0 Then Exit
If Result=1 Then
  Do
    Dest="'Kill'"
    Call Kill
  End
If Result=2 Then
  Do
    Dest="'Accept'"
    Call Accept
  End

/* let's write the new configuration file */
Call Open(newfile,UULibPath,w)
Call Writeln(newfile,txt2)

/* Let's tell the user what we have done */
Address THOR.01
REQUESTNOTIFY TEXT '"'vers'\n\n The following EMail address has been\n added to the 'dest' section of the\n      GetMail configuration file.\n\n'addr'\n" BT "_Thank You"'

Exit

/* Let's find the end of the 'Kill Addresses' section and insert the new address */
Kill:
Call Check
Do x=1 To lines
  If txt.x="#  Allowed Addresses" Then
    Do
      x=x-1
      Leave
    End
End
  bar=Length(txt.x)+3
  pos=Index(txt,"#  Allowed Addresses")
  insertpos=pos-bar
  txt2=Insert(addr||lf,txt,insertpos)
Return

/* Let's find the end of the 'Allowed Addresses' section and insert the new address */
Accept:
  Call Check
  insertpos=Index(txt,"# EOF")-2
  txt2=Insert(addr||lf,txt,insertpos)
Return

/* Let's make sure that the user really wants to do this */
Check:
  Address THOR.01
  REQUESTNOTIFY TEXT '"'vers'\n\n     Are you sure that you wish to\n    add the following EMail address\n     to the 'dest' section of the\n      GetMail configuration file?\n\n'addr'\n" BT "_Positive!|Perhaps Not"'
  If Result=0 Then Exit
Return

Syntax:
  Address THOR.01
  REQUESTNOTIFY TEXT '"'vers'\n\nA syntax error ('RC') occurred.\n'ErrorText(RC)'\nin line 'SIGL'" BT "_Exit"'
  Exit
Return

BBSError:
  Address THOR.01
  REQUESTNOTIFY TEXT '"'vers'\n\nBBSREAD ERROR\n'BBSREAD.LASTERROR'" BT "_Exit"'
  Exit
Return